Program Statements

The END statement terminates script execution normally.

STOP

The STOP statement interrupts script execution, returns a “STOP” error, and invokes the debugger. Use the cont command at the debugger prompt to continue execution of the script or the step command to execute a single step in the script.

GOTO

GOTO label

The GOTO statement transfers program control to the line number specified by label. The GOTO label statement results in a branching operation. A label is an identifier terminated with a colon on a line that contains no other statements or expressions. 

mylabel:
print "Hello World"
goto mylabel

RETURN

RETURN expression

The RETURN statement returns from a function back to its caller. If the function is not type Void, RETURN can also return a value to the caller.

PRINT

PRINT [#output_object], [@location], item list

The PRINT statement prints an item or list of items in the console. The item(s) may be strings, integers, floats, variables, or expressions. An object with an ifInt, ifFloat, or ifString interface may also be printed. If the output_object is specified, this statement will print to an object with an ifStreamSend interface.

If the statement is printing a list of items, the items must be separated with semicolons or commas. If semicolons are used, spaces are not inserted between printed items; if commas are used, the cursor will automatically advance to the next print zone before printing the next item.

Positive numbers and zero are printed with a leading space (without a plus sign). Spaces are not inserted before or after strings.

x = 5 : print 25; " is equal to"; x ^2  
' prints "25 is equal to 25"

a$ = "string"
print a$;a$,a$;" ";a$
'prints "stringstring	string string"

> print "zone 1","zone 2","zone 3","zone 4"
'prints "zone 1          zone 2           zone 3           zone 4"

print "print statement #1 ";
print "print statement #2"
'prints "print statement #1 print statement #2"

Print "this is a five "5"!!"

[@location]

If the console you are printing to has the ifTextField interface, you can use the @ character to specify where printing will begin.

print #m.text_field,@width*(height/2-1)+(width-len(msg$))/2,msg$;

Whenever you use PRINT @ on the bottom line of the display, an automatic line-feed causes all displayed lines to move up one line. To prevent this from happening, use a trailing semicolon at the end of the statement.

TAB (expression)

This statement moves the cursor to the specified position on the current line (modulo the width of the console if the TAB position is greater than the console width).

print tab(5)"tabbed 5";tab(25)"tabbed 25"

Note the following about the TAB statement:

• The TAB statement may be used several times in a PRINT list.
• No punctuation is required after a TAB statement.
• Numerical expressions may be used to specify a TAB position.
• The TAB statement cannot be used to move the cursor to the left.
• If the cursor is beyond the specified position, the TAB statement is ignored.

POS(x)

This statement returns an integer that indicates the current cursor position from 0 to the maximum width of the window. This statement requires a dummy argument in the form of any numeric expression.

print tab(40) pos(0)   'prints 40 at position 40

print "these" tab(pos(0)+5)"words" tab(pos(0)+5)"are";
print tab(pos(0)+5)"evenly" tab(pos(0)+5)"spaced"

FOR / END FOR

FOR counter_variable = initial_value TO final_value STEP increment / END FOR <or> NEXT

The FOR statement creates an iterative loop that allows a sequence of program statements to be executed a specified number of times.

The initial_value, final_value, and increment can be any expression. The first time the FOR statement is executed, these three variables are evaluated and their values are saved; changing the variables during the loop will have no affect on the operation of the loop. However, the counter_variable must not be changed, or the loop will not operate normally. The first time the FOR statement is executed, the counter is set to both the value and type of the initial_value.

At the beginning of each loop, the value of the counter_variable is compared with the final_value. If the value of the counter_variable is greater than the final_value, the loop will complete and execution will continue with the statement following the END FOR (or NEXT) statement. If, on the other hand, the counter has not yet exceeded the final_value, control passes to the first statement after the FOR statement. If increment is a negative number, the loop will complete when the value of the counter_variable is less than the final_value.

When program flow reaches the END FOR (or NEXT) statement, the counter is incremented by the specified increment amount (or decremented if increment is a negative value). If the STEP [increment] language is not included in the FOR statement, the increment defaults to 1.

Use EXIT FOR to exit a FOR block prematurely.

The following script decrements i at the beginning of each loop until it is less than 1.

for i=10 to 1 step -1
       print i
end for

FOR EACH IN / END FOR

aa={joe: 10, fred: 11, sue:9}
For each n in aa
   Print n;aa[n]
   aa.delete[n]
end for

values = {a: 1, b: 2, c: 3, d: 4, e: 5, f: 6}

for each key_outer in values
	print "outer: ";key_outer;" : ";values[key_outer]
	for each key_inner in values 'THIS WILL CAUSE PROBLEMATIC BEHAVIOR
		print "inner: ";key_inner;" : ";values[key_inner]
	end for
end for

values = {a: 1, b: 2, c: 3, d: 4, e: 5, f: 6}
valuesArray = []

for each key in values 'Copy the keys to an array
	valuesArray.push(key)
end for

for each key_outer in values
	print "outer: ";key_outer;" : ";values[key_outer]
	for each key_inner in valuesArray 'Iterate over the array of keys
		print "inner: ";key_inner;" : ";values[key_inner]
	end for
end for

k=0
while k<>0
   k=1
   Print "loop once"
end while
 
while true
   Print "loop once"
   Exit while
End while

if x>127 then print "out of range" : end

if y=m then m=o 'won't work without THEN

If BooleanExpression [ Then ]
   [ Block ]
   [ ElseIfStatement+ ]
   [ ElseStatement ]
End If
 
ElseIfStatement ::=
   ElseIf BooleanExpression [ Then ]
   [ Block ]
 
ElseStatement ::=
   Else
   [ Block ]

vp_msg_loop:
        msg=wait(tiut, p)
        if type(msg)="rovideoevent" then                                            
            if debug then print "video event";msg.getint()
            if lm=0 and msg.getint() = meden then
                if debug then print "videofinished"
                retcode=5
                return
            endif
        else if type(msg)="rogpiobutton" then
            if debug then print "button press";msg
            if esc0 and msg=b0 then retcode=1:return
            if esc1 and msg=b1 then retcode=2:return
            if esc2 and msg=b2 then retcode=3:return
            if esc3 and msg=b3 then retcode=4:return
        else if type(msg)=" Invalid" then
            if debug then print "timeout"
            retcode=6
            return
        endif
 
        goto vp_msg_loop

sub main()
   obj={
       add: add
       a: 5
       b: 10
       }
 
   obj.add()
   print obj.result
end sub
 
function add() As void
    m.result=m.a+m.b
end function

myfunc=function (a, b)
       Return a+b
end function
 
print myfunc(1,2)

q = {
 
starring : function(o, e)
str = e.GetBody()
print "Starring: " + str 
toks = box(str).tokenize(",")
for each act in toks
actx = box(act).trim()
if actx <> "" then
print "Actor: [" + actx + "]"
                o.Actors.Push(actx)
endif
end for
return 0
end function
}
 
q.starring(myobj, myxml)